Function Reference

_GUIToolTip_SetMaxTipWidth

Sets the maximum width for a ToolTip window

 #include <GuiToolTip.au3>
_GUIToolTip_SetMaxTipWidth ( $hWnd, $iWidth )

Parameters

$hWnd Handle to the ToolTip control (returned by _GUIToolTip_Create.)
$iWidth Maximum ToolTip window width to be set (in pixels)

Return Value

Returns the previous maximum ToolTip width in pixels.

Remarks

The maximum ToolTip width value does not indicate a ToolTip window's actual width.
Rather, if a ToolTip string exceeds the maximum width, the control breaks the text into multiple lines, using spaces to determine line breaks.
If the text cannot be segmented into multiple lines, it will be displayed on a single line.
The length of this line may exceed the maximum ToolTip width.

A ToolTip control needs this setting if you want to have a multi-line ToolTip. Without this setting, if you put a line break (@CR, @LF, @CRLF) in the text of a tool, the text will be truncated at that line break.

Related

_GUIToolTip_GetMaxTipWidth

Example

#include <GUIConstantsEx.au3>
#include <GUIToolTip.au3>

Example()

Func Example()
    Local $hGUI = GUICreate(StringTrimRight(@ScriptName, 4), 350, 200)

    Local $iButton = GUICtrlCreateButton("Button ToolTip", 30, 32, 130, 28)
    Local $hButton = GUICtrlGetHandle($iButton)

    ; Create a tooltip control
    Local $hToolTip = _GUIToolTip_Create($hGUI)
    ; Set the maximum width to 400 pixels
    _GUIToolTip_SetMaxTipWidth($hToolTip, 400)

    _GUIToolTip_AddTool($hToolTip, 0, 'If the text exceeds the width, then it carries over to the next line.' & @CRLF & 'Also allows you to use @CRLF', $hButton)
    GUISetState()

    While 1
        If GUIGetMsg() = $GUI_EVENT_CLOSE Then ExitLoop
    WEnd
    ; Destroy the tooltip control
    _GUIToolTip_Destroy($hToolTip)
    GUIDelete($hGUI)
EndFunc   ;==>Example